diff --git a/Makefile.am b/Makefile.am
index a20f1bc..df1a60d 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -1,71 +1,71 @@
 # Makefile.am - Top level Makefile for scute.
 # Copyright (C) 2006 g10 Code GmbH
 #
 # This file is part of Scute.
 #
 # Scute is free software; you can redistribute it and/or modify it
 # under the terms of the GNU Lesser General Public License as
 # published by the Free Software Foundation; either version 2.1 of
 # the License, or (at your option) any later version.
 #
 # Scute is distributed in the hope that it will be useful, but
 # WITHOUT ANY WARRANTY; without even the implied warranty of
 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
 # Lesser General Public License for more details.
 #
 # You should have received a copy of the GNU Lesser General Public
 # License along with this program; if not, see <https://gnu.org/licenses/>.
 # SPDX-License-Identifier: LGPL-2.1-or-later
 
 ## Process this file with automake to produce Makefile.in
 
 AM_DISTCHECK_DVI_TARGET = pdf
 
 ACLOCAL_AMFLAGS = -I m4
 AUTOMAKE_OPTIONS = dist-bzip2 no-dist-gzip
 
-EXTRA_DIST = autogen.sh README.GIT VERSION
+EXTRA_DIST = autogen.sh README.GIT VERSION build-aux/libtool-patch.sed
 
 if RUN_TESTS
 tests = tests
 else
 tests =
 endif
 
 if BUILD_DOC
 doc = doc
 else
 doc =
 endif
 
 SUBDIRS = m4 src ${tests} ${doc}
 
 dist-hook: gen-ChangeLog
 
 distcheck-hook:
 	set -e; ( \
 	pref="#+macro: scute_" ;\
 	reldate="$$(date -u +%Y-%m-%d)" ;\
         echo "$${pref}ver  $(PACKAGE_VERSION)"  ;\
         echo "$${pref}date $${reldate}" ;\
         list='$(DIST_ARCHIVES)'; for i in $$list; do \
 	  case "$$i" in *.tar.bz2) \
             echo "$${pref}size $$(wc -c <$$i|awk '{print int($$1/1024)}')k" ;\
 	    echo "$${pref}sha1 $$(sha1sum <$$i|cut -d' ' -f1)" ;\
 	    echo "$${pref}sha2 $$(sha256sum <$$i|cut -d' ' -f1)" ;;\
 	  esac;\
 	done ) | tee $(distdir).swdb
 
 .PHONY: gen-ChangeLog release sign-release
 
 gen_start_date = 2011-12-01T00:00:00
 gen-ChangeLog:
 	if test -d $(top_srcdir)/.git; then				\
 	  (cd $(top_srcdir) &&                      			\
 	    $(GITLOG_TO_CHANGELOG) --append-dot --tear-off		\
 	    --amend=build-aux/git-log-fix				\
 	    --since=$(gen_start_date) ) > $(distdir)/cl-t;		\
           cat $(top_srcdir)/build-aux/git-log-footer >> $(distdir)/cl-t;\
 	  rm -f $(distdir)/ChangeLog;					\
 	  mv $(distdir)/cl-t $(distdir)/ChangeLog;			\
 	fi
diff --git a/build-aux/libtool-patch.sed b/build-aux/libtool-patch.sed
new file mode 100644
index 0000000..ac5a3ba
--- /dev/null
+++ b/build-aux/libtool-patch.sed
@@ -0,0 +1,68 @@
+#
+# This is a sed script to patch the generated libtool,
+# which works well against both of libtool 2.4.2 and 2.4.7.
+#
+# You may use this work under the terms of a Creative Commons CC0 1.0
+# License/Waiver.
+#
+# CC0 Public Domain Dedication
+# https://creativecommons.org/publicdomain/zero/1.0/
+
+#
+# This sed script applys two hunks of the patch:
+#
+#     Part1: after the comment "# bleh windows"
+#     Part2: after the comment "#extension on DOS 8.3..."
+#
+# Only when those two parts are patched correctly, it exits with 0 or
+# else, it exits with 1
+#
+
+# Find the part 1, by the comment
+/^[ \t]*# bleh windows$/b part1_start
+# Not found the part1, raise an error
+$ q1
+b
+
+:part1_start
+n
+# The first line in the part 1 must be the begining of the case statement.
+/^[ \t]*case \$host in$/! q1
+n
+# Insert the entry for x86_64-*mingw32*, for modified versuffix.
+i\
+	      x86_64-*mingw32*)
+i\
+		func_arith $current - $age
+i\
+		major=$func_arith_result
+i\
+		versuffix="6-$major"
+i\
+		;;
+:part1_0
+# Find the end of the case statement
+/^[ \t]*esac$/b find_part2
+# Not found the end of the case statement, raise an error
+$ q1
+n
+b part1_0
+
+:find_part2
+/^[ \t]*# extension on DOS 8.3 file.*systems.$/b part2_process
+# Not found the part2, raise an error
+$ q1
+n
+b find_part2
+
+:part2_process
+$ q1
+s/^[ \t]*\(versuffix=\)\(.*\)\(-$major\)\(.*\)$/\t  case \$host in\n\t  x86_64-*mingw32*)\n\t    \1\26\3\4\n\t    ;;\n\t  *)\n\t    \1\2\3\4\n\t    ;;\n\t  esac/
+t part2_done
+n
+b part2_process
+
+:part2_done
+$ q0
+n
+b part2_done
diff --git a/configure.ac b/configure.ac
index c3d58cf..79e84a7 100644
--- a/configure.ac
+++ b/configure.ac
@@ -1,358 +1,396 @@
 # configure.ac: Configure script for Scute.
 # Copyright (C) 2006, 2007, 2008, 2009, 2010, 2015 g10 Code GmbH
 #
 # This file is part of Scute.
 #
 # Scute is free software; you can redistribute it and/or modify it
 # under the terms of the GNU Lesser General Public License as
 # published by the Free Software Foundation; either version 2.1 of
 # the License, or (at your option) any later version.
 #
 # Scute is distributed in the hope that it will be useful, but
 # WITHOUT ANY WARRANTY; without even the implied warranty of
 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
 # Lesser General Public License for more details.
 #
 # You should have received a copy of the GNU Lesser General Public
 # License along with this program; if not, see <https://gnu.org/licenses/>.
 # SPDX-License-Identifier: LGPL-2.1-or-later
 
 # Process this file with autoconf to produce a configure script.
 
 AC_PREREQ([2.61])
 min_automake_version="1.16.3"
 
 # To build a release you need to create a tag with the version number
 # (git tag -s scute-1.n.m) and run "./autogen.sh --force".  Please
 # bump the version number immediately *after* the release and do
 # another commit and push so that the git magic is able to work.
 m4_define([mym4_package],[scute])
 m4_define([mym4_major], [1])
 m4_define([mym4_minor], [7])
 m4_define([mym4_micro], [1])
 
 # To start a new development series, i.e a new major or minor number
 # you need to mark an arbitrary commit before the first beta release
 # with an annotated tag.  For example the 1.5 branch starts off with
 # the tag "scute-1.5-base".  This is used as the base for counting
 # beta numbers before the first release of a series.
 
 # Below is m4 magic to extract and compute the git revision number,
 # the decimalized short revision number, a beta version string and a
 # flag indicating a development version (mym4_isbeta).  Note that the
 # m4 processing is done by autoconf and not during the configure run.
 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
 m4_esyscmd([echo ]mym4_version[>VERSION])
 AC_INIT([mym4_package],[mym4_version],[https://bugs.gnupg.org])
 
 # LT Version numbers, remember to change them just *before* a release.
 #   (Code changed:			REVISION++)
 #   (Interfaces added/removed/changed:	CURRENT++, REVISION=0)
 #   (Interfaces added:			AGE++)
 #   (Interfaces removed/changed:	AGE=0)
 #
 LIBSCUTE_LT_CURRENT=0
 LIBSCUTE_LT_AGE=0
 LIBSCUTE_LT_REVISION=5
 
 # Version numbers reported by the PKCS #11 module to its users.
 VERSION_MAJOR=1
 VERSION_MINOR=0
 
 NEED_GPG_ERROR_VERSION=1.38
 NEED_LIBASSUAN_VERSION=2.5.0
 
 # Some status variables to give feedback at the end of a configure run.
 have_gpg_error=no
 have_libassuan=no
 
 #
 # Provide information about the build.
 #
 BUILD_REVISION="mym4_revision"
 BUILD_REVISION_DEC="mym4_revision_dec"
 
 PACKAGE=$PACKAGE_NAME
 VERSION=$PACKAGE_VERSION
 
 AC_CONFIG_AUX_DIR([build-aux])
 AC_CONFIG_SRCDIR([src/cryptoki.h])
 AC_CONFIG_HEADERS([config.h])
 AC_CONFIG_MACRO_DIR(m4)
 AM_INIT_AUTOMAKE
 AM_MAINTAINER_MODE
 AC_CANONICAL_HOST
 
 # Autobuilder support.
 AB_INIT
 
 # Enable GNU extensions on systems that have them.
 AC_USE_SYSTEM_EXTENSIONS
 
 AH_VERBATIM([_REENTRANT],
 [/* To allow the use of scute in multithreaded programs we have to use
   special features from the library.  */
 #ifndef _REENTRANT
 # define _REENTRANT 1
 #endif])
 
 # Checks for programs.
 AC_PROG_CC
 
 # Check for programs needed for the manual.
 AC_CHECK_PROG(YAT2M, yat2m, yat2m)
 have_doc_tools=no
 if test -n "$ac_cv_prog_YAT2M" ; then
     have_doc_tools=yes
 fi
 
 # Note: A suitable gitlog-to-changelog script can be found in GnuPG master.
 AC_CHECK_PROGS(GITLOG_TO_CHANGELOG, gitlog-to-changelog, [gitlog-to-changelog])
 
 #
 # Setup gcc specific options
 #
 AC_MSG_NOTICE([checking for cc features])
 if test "$GCC" = yes; then
     mycflags=
     mycflags_save=$CFLAGS
 
     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
     # options.  This is the case for gcc >= 4.6
     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
 #kickerror
 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
     AC_MSG_RESULT($_gcc_silent_wno)
 
     # Note that it is okay to use CFLAGS here because these are just
     # warning options and the user should have a chance of overriding
     # them.
     if test "$USE_MAINTAINER_MODE" = "yes"; then
         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
         if test x"$_gcc_silent_wno" = xyes ; then
           _gcc_wopt=yes
         else
           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
           CFLAGS="-Wno-missing-field-initializers"
           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
                             [_gcc_wopt=yes],[_gcc_wopt=no])
           AC_MSG_RESULT($_gcc_wopt)
         fi
         if test x"$_gcc_wopt" = xyes ; then
           mycflags="$mycflags -W -Wno-sign-compare"
           mycflags="$mycflags -Wno-missing-field-initializers"
         fi
 
         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
         CFLAGS="-Wdeclaration-after-statement"
         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
         AC_MSG_RESULT($_gcc_wopt)
         if test x"$_gcc_wopt" = xyes ; then
           mycflags="$mycflags -Wdeclaration-after-statement"
         fi
     else
         mycflags="$mycflags -Wall"
     fi
 
     if test x"$_gcc_silent_wno" = xyes ; then
       _gcc_psign=yes
     else
       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
       CFLAGS="-Wno-pointer-sign"
       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
                         [_gcc_psign=yes],[_gcc_psign=no])
       AC_MSG_RESULT($_gcc_psign)
     fi
     if test x"$_gcc_psign" = xyes ; then
        mycflags="$mycflags -Wno-pointer-sign"
     fi
 
     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
     CFLAGS="-Wpointer-arith"
     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
     AC_MSG_RESULT($_gcc_psign)
     if test x"$_gcc_psign" = xyes ; then
        mycflags="$mycflags -Wpointer-arith"
     fi
 
     CFLAGS="$mycflags $mycflags_save"
 fi
 
 AC_ARG_ENABLE(optimization,
    AS_HELP_STRING([--disable-optimization],
                   [disable compiler optimization]),
                   [if test $enableval = no ; then
                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
                    fi])
 
 #
 # Option to disable building of doc file
 #
 build_doc=yes
 AC_ARG_ENABLE([doc], AS_HELP_STRING([--disable-doc],
                                     [do not build the documentation]),
                      build_doc=$enableval, build_doc=yes)
 AM_CONDITIONAL([BUILD_DOC], [test "x$build_doc" != xno && test "x$have_doc_tools" = xyes])
 
 
 
 AC_SUBST(LIBSCUTE_LT_CURRENT)
 AC_SUBST(LIBSCUTE_LT_AGE)
 AC_SUBST(LIBSCUTE_LT_REVISION)
 AC_SUBST(PACKAGE)
 AC_SUBST(VERSION)
 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
 AC_DEFINE_UNQUOTED(VERSION_MAJOR, $VERSION_MAJOR, [Major version number])
 AC_DEFINE_UNQUOTED(VERSION_MINOR, $VERSION_MINOR, [Minor version number])
 
 # Don't default to build static libs.
 # FIXME: Caution: Evil hack ahead.  Libtool does not support linking a
 # static library to a shared library.  But for libassuan, we need this.
 # Instead adding a lot of junk to Makefile.am to get this, we just override
 # all safety checks here.  We are driving without seat belts now!
 # http://lists.cairographics.org/archives/cairo/2009-April/016962.html
 lt_cv_deplibs_check_method=pass_all
 
 LT_PREREQ([2.2.6])
 LT_INIT([win32-dll disable-static])
 LT_LANG([Windows Resource])
 
 # For now we hardcode the use of version scripts.  It would be better
 # to write a test for this or even implement this within libtool.
 have_ld_version_script=no
 case "${host}" in
     *-*-linux*)
 	have_ld_version_script=yes
         ;;
     *-*-gnu*)
 	have_ld_version_script=yes
         ;;
     *-apple-darwin*)
         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
                   Expose all libc features (__DARWIN_C_FULL).)
         AC_DEFINE(_XOPEN_SOURCE, 500, Activate POSIX interface on MacOS X)
         ;;
 esac
 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 
+#
+# Specify how we support our local modification of libtool for Windows
+# 64-bit.  Options are:
+#
+# (1) apply: when appying patch fails, it results failure of entire build
+# (2) never: never apply the patch (no try)
+# (3) try: use patched if it goes well, use original if fails
+#
+AC_ARG_WITH([libtool-modification],
+  AS_HELP_STRING([--with-libtool-modification=apply|never|try],
+                 [how to handle libtool modification (default=apply)]),
+                 build_libtool_modification=$withval,
+                 build_libtool_modification=apply)
+
+#
+# Apply a patch (locally maintained one of ours) to libtool
+#
+case $host in
+  x86_64-*mingw32*)
+AC_CONFIG_COMMANDS([libtool-patch],[[
+  if test "$build_selection" = never; then
+    echo "patch not applied"
+  elif (mv -f libtool libtool.orig; \
+        sed -f $srcdir/build-aux/libtool-patch.sed libtool.orig >libtool); then
+    echo "applied successfully"
+  elif test "$build_selection" = try; then
+    mv -f libtool.orig libtool
+    echo "patch failed, thus, using original"
+  else
+    echo "patch failed"
+    as_fn_exit 1
+  fi
+]],[build_selection=$build_libtool_modification])
+  ;;
+  *)
+  ;;
+esac
+
 have_w32_system=no
 have_darwin_system=no
 case "${host}" in
     *-mingw32*)
         # special stuff for Windows NT
 	have_w32_system=yes
         ;;
     *-apple-darwin*)
         have_darwin_system=yes
         ;;
     *)
 	;;
 esac
 
 if test "$have_w32_system" = yes; then
    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
 fi
 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
 AM_CONDITIONAL(HAVE_DARWIN_SYSTEM, test "$have_darwin_system" = yes)
 
 # Generate values for the DLL version info
 if test "$have_w32_system" = yes; then
     BUILD_TIMESTAMP=`date --iso-8601=minutes`
     changequote(,)dnl
     BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
     changequote([,])dnl
     BUILD_FILEVERSION="${BUILD_FILEVERSION}${BUILD_REVISION_DEC}"
 fi
 AC_SUBST(BUILD_REVISION)
 AC_SUBST(BUILD_REVISION_DEC)
 AC_SUBST(BUILD_TIMESTAMP)
 AC_SUBST(BUILD_FILEVERSION)
 
 # The error code library.  Error codes are sent over the IPC layer and
 # have to be interpreted.
 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
                   have_gpg_error=yes, have_gpg_error=no)
 
 # The IPC library.
 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
                   have_libassuan=yes, have_libassuan=no)
 
 
 
 # Checks for header files.
 AC_CHECK_HEADERS([stdlib.h string.h])
 
 # Checks for typedefs, structures, and compiler characteristics.
 AC_HEADER_STDBOOL
 AC_C_INLINE
 
 # Checks for library functions.
 AC_CHECK_FUNCS([ttyname localtime_r timegm stpcpy])
 
 # Test if tests can be run
 ok=yes
 AM_CONDITIONAL(RUN_TESTS, test "$ok" = "yes")
 
 
 AH_BOTTOM([
 /* Prefix all estream functions.  */
 #define _ESTREAM_EXT_SYM_PREFIX _scute_
 ])
 
 
 # Print errors here so that they are visible all
 # together and the user can acquire them all together.
 
 die=no
 if test "$have_gpg_error" = "no"; then
    die=yes
    AC_MSG_NOTICE([[
 ***
 *** You need libgpg-error to build this program.
 *** This library is for example available at
 ***   ftp://ftp.gnupg.org/pub/gcrypt/libgpg-error
 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
 ***]])
 fi
 if test "$have_libassuan" = "no"; then
    die=yes
    AC_MSG_NOTICE([[
 ***
 *** You need libassuan to build this program.
 *** This library is for example available at
 ***   ftp://ftp.gnupg.org/pub/gcrypt/alpha/libassuan/
 *** (at least version $NEED_LIBASSUAN_VERSION is required).
 ***]])
 fi
 
 if test "$die" = "yes"; then
     AC_MSG_ERROR([[
 ***
 *** Required libraries not found. Please consult the above messages
 *** and install them before running configure again.
 ***]])
 fi
 
 AC_CONFIG_FILES([Makefile
                  m4/Makefile
                  src/Makefile
                  tests/Makefile
 		 doc/Makefile
                  src/versioninfo.rc])
 AC_OUTPUT
 
 echo "
         Scute v${VERSION} has been configured as follows:
 
         Revision: mym4_revision  (mym4_revision_dec)
         Platform: $host
 "