diff --git a/m4/gpg-error.m4 b/m4/gpg-error.m4
index f89a4ee..70dc501 100644
--- a/m4/gpg-error.m4
+++ b/m4/gpg-error.m4
@@ -1,136 +1,149 @@
 # gpg-error.m4 - autoconf macro to detect libgpg-error.
 # Copyright (C) 2002, 2003, 2004, 2011, 2014, 2018 g10 Code GmbH
 #
 # This file is free software; as a special exception the author gives
 # unlimited permission to copy and/or distribute it, with or without
 # modifications, as long as this notice is preserved.
 #
 # This file is distributed in the hope that it will be useful, but
 # WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
 #
-# Last-changed: 2018-10-25
+# Last-changed: 2018-10-26
 
 
 dnl AM_PATH_GPG_ERROR([MINIMUM-VERSION,
 dnl                   [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
 dnl
 dnl Test for libgpg-error and define GPG_ERROR_CFLAGS, GPG_ERROR_LIBS,
 dnl GPG_ERROR_MT_CFLAGS, and GPG_ERROR_MT_LIBS.  The _MT_ variants are
 dnl used for programs requireing real multi thread support.
 dnl
 dnl If a prefix option is not used, the config script is first
 dnl searched in $SYSROOT/bin and then along $PATH.  If the used
 dnl config script does not match the host specification the script
 dnl is added to the gpg_config_script_warn variable.
 dnl
 AC_DEFUN([AM_PATH_GPG_ERROR],
 [ AC_REQUIRE([AC_CANONICAL_HOST])
   gpg_error_config_prefix=""
   dnl --with-libgpg-error-prefix=PFX is the preferred name for this option,
   dnl since that is consistent with how our three siblings use the directory/
   dnl package name in --with-$dir_name-prefix=PFX.
   AC_ARG_WITH(libgpg-error-prefix,
               AC_HELP_STRING([--with-libgpg-error-prefix=PFX],
                              [prefix where GPG Error is installed (optional)]),
               [gpg_error_config_prefix="$withval"])
 
   dnl Accept --with-gpg-error-prefix and make it work the same as
   dnl --with-libgpg-error-prefix above, for backwards compatibility,
   dnl but do not document this old, inconsistently-named option.
   AC_ARG_WITH(gpg-error-prefix,,
               [gpg_error_config_prefix="$withval"])
 
   if test x"${GPG_ERROR_CONFIG}" = x ; then
      if test x"${gpg_error_config_prefix}" != x ; then
         GPG_ERROR_CONFIG="${gpg_error_config_prefix}/bin/gpg-error-config"
      else
        case "${SYSROOT}" in
          /*)
            if test -x "${SYSROOT}/bin/gpg-error-config" ; then
              GPG_ERROR_CONFIG="${SYSROOT}/bin/gpg-error-config"
            fi
            ;;
          '')
            ;;
           *)
            AC_MSG_WARN([Ignoring \$SYSROOT as it is not an absolute path.])
            ;;
        esac
      fi
   fi
 
   AC_PATH_PROG(GPG_ERROR_CONFIG, gpg-error-config, no)
   min_gpg_error_version=ifelse([$1], ,1.33,$1)
   ok=no
+
+  use_gpgrt_config=""
   if test "$GPG_ERROR_CONFIG" = "no"; then
     AC_PATH_PROG(GPGRT_CONFIG, gpgrt-config, no)
     if CC=$CC $GPGRT_CONFIG gpg-error >/dev/null 2>&1; then
       GPG_ERROR_CONFIG="$GPGRT_CONFIG gpg-error"
+      use_gpgrt_config=yes
       gpg_error_config_version=`CC=$CC $GPG_ERROR_CONFIG --modversion`
     fi
   else
     gpg_error_config_version=`CC=$CC $GPG_ERROR_CONFIG --version`
   fi
   if test "$GPG_ERROR_CONFIG" != "no"; then
     req_major=`echo $min_gpg_error_version | \
                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
     req_minor=`echo $min_gpg_error_version | \
                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
     major=`echo $gpg_error_config_version | \
                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
     minor=`echo $gpg_error_config_version | \
                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
     if test "$major" -gt "$req_major"; then
         ok=yes
     else
         if test "$major" -eq "$req_major"; then
             if test "$minor" -ge "$req_minor"; then
                ok=yes
             fi
         fi
     fi
     if test -z "$GPGRT_CONFIG"; then
       if test "$major" -gt 1 -o "$major" -eq 1 -a "$minor" -ge 33; then
         AC_PATH_PROG(GPGRT_CONFIG, gpgrt-config, no)
         GPG_ERROR_CONFIG="$GPGRT_CONFIG gpg-error"
+        use_gpgrt_config=yes
       fi
     fi
   fi
   AC_MSG_CHECKING(for GPG Error - version >= $min_gpg_error_version)
   if test $ok = yes; then
     GPG_ERROR_CFLAGS=`CC=$CC $GPG_ERROR_CONFIG --cflags`
     GPG_ERROR_LIBS=`CC=$CC $GPG_ERROR_CONFIG --libs`
-    GPG_ERROR_MT_CFLAGS=`CC=$CC $GPG_ERROR_CONFIG --variable=mtcflags 2>/dev/null`
-    GPG_ERROR_MT_CFLAGS="$GPG_ERROR_CFLAGS${GPG_ERROR_CFLAGS:+ }$GPG_ERROR_MT_CFLAGS"
-    GPG_ERROR_MT_LIBS=`CC=$CC $GPG_ERROR_CONFIG --variable=mtlibs 2>/dev/null`
-    GPG_ERROR_MT_LIBS="$GPG_ERROR_LIBS${GPG_ERROR_LIBS:+ }$GPG_ERROR_MT_LIBS"
+    if test -z "$use_gpgrt_config"; then
+      GPG_ERROR_MT_CFLAGS=`CC=$CC $GPG_ERROR_CONFIG $gpg_error_config_args --mt --cflags 2>/dev/null`
+      GPG_ERROR_MT_LIBS=`CC=$CC $GPG_ERROR_CONFIG $gpg_error_config_args --mt --libs 2>/dev/null`
+    else
+      GPG_ERROR_MT_CFLAGS=`CC=$CC $GPG_ERROR_CONFIG --variable=mtcflags 2>/dev/null`
+      GPG_ERROR_MT_CFLAGS="$GPG_ERROR_CFLAGS${GPG_ERROR_CFLAGS:+ }$GPG_ERROR_MT_CFLAGS"
+      GPG_ERROR_MT_LIBS=`CC=$CC $GPG_ERROR_CONFIG --variable=mtlibs 2>/dev/null`
+      GPG_ERROR_MT_LIBS="$GPG_ERROR_LIBS${GPG_ERROR_LIBS:+ }$GPG_ERROR_MT_LIBS"
+    fi
     AC_MSG_RESULT([yes ($gpg_error_config_version)])
     ifelse([$2], , :, [$2])
-    gpg_error_config_host=`CC=$CC $GPG_ERROR_CONFIG --variable=host 2>/dev/null || echo none`
+    if test -z "$use_gpgrt_config"; then
+      gpg_error_config_host=`CC=$CC $GPG_ERROR_CONFIG --host 2>/dev/null || echo none`
+    else
+      gpg_error_config_host=`CC=$CC $GPG_ERROR_CONFIG --variable=host 2>/dev/null || echo none`
+    fi
     if test x"$gpg_error_config_host" != xnone ; then
       if test x"$gpg_error_config_host" != x"$host" ; then
   AC_MSG_WARN([[
 ***
-*** The config script $GPG_ERROR_CONFIG was
+*** The config script "$GPG_ERROR_CONFIG" was
 *** built for $gpg_error_config_host and thus may not match the
 *** used host $host.
 *** You may want to use the configure option --with-libgpg-error-prefix
 *** to specify a matching config script or use \$SYSROOT.
 ***]])
         gpg_config_script_warn="$gpg_config_script_warn libgpg-error"
       fi
     fi
   else
     GPG_ERROR_CFLAGS=""
     GPG_ERROR_LIBS=""
     GPG_ERROR_MT_CFLAGS=""
     GPG_ERROR_MT_LIBS=""
     AC_MSG_RESULT(no)
     ifelse([$3], , :, [$3])
   fi
   AC_SUBST(GPG_ERROR_CFLAGS)
   AC_SUBST(GPG_ERROR_LIBS)
   AC_SUBST(GPG_ERROR_MT_CFLAGS)
   AC_SUBST(GPG_ERROR_MT_LIBS)
 ])
diff --git a/src/ntbtls.m4 b/src/ntbtls.m4
index 67d314a..665ae00 100644
--- a/src/ntbtls.m4
+++ b/src/ntbtls.m4
@@ -1,147 +1,159 @@
 dnl Autoconf macros for NTBTLS
 dnl Copyright (C) 2002, 2004, 2011 Free Software Foundation, Inc.
 dnl
 dnl This file is free software; as a special exception the author gives
 dnl unlimited permission to copy and/or distribute it, with or without
 dnl modifications, as long as this notice is preserved.
 dnl
 dnl This file is distributed in the hope that it will be useful, but
 dnl WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
 dnl implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
 
 
 dnl AM_PATH_NTBTLS([MINIMUM-VERSION,
 dnl                   [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
 dnl
 dnl Test for NTBTLS and define NTBTLS_CFLAGS and NTBTLS_LIBS.
 dnl MINIMUN-VERSION is a string with the version number optionalliy prefixed
 dnl with the API version to also check the API compatibility. Example:
 dnl a MINIMUN-VERSION of 1:1.2.5 won't pass the test unless the installed
 dnl version of libgcrypt is at least 1.2.5 *and* the API number is 1.  Using
 dnl this features allows to prevent build against newer versions of libgcrypt
 dnl with a changed API.
 dnl
 AC_DEFUN([AM_PATH_NTBTLS],
 [ AC_REQUIRE([AC_CANONICAL_HOST])
   AC_ARG_WITH(ntbtls-prefix,
             AC_HELP_STRING([--with-ntbtls-prefix=PFX],
                            [prefix where NTBTLS is installed (optional)]),
      ntbtls_config_prefix="$withval", ntbtls_config_prefix="")
   if test x"${NTBTLS_CONFIG}" = x ; then
      if test x"${ntbtls_config_prefix}" != x ; then
         NTBTLS_CONFIG="${ntbtls_config_prefix}/bin/ntbtls-config"
      else
        case "${SYSROOT}" in
          /*)
            if test -x "${SYSROOT}/bin/ntbtls-config" ; then
              NTBTLS_CONFIG="${SYSROOT}/bin/ntbtls-config"
            fi
            ;;
          '')
            ;;
           *)
            AC_MSG_WARN([Ignoring \$SYSROOT as it is not an absolute path.])
            ;;
        esac
      fi
   fi
 
   use_gpgrt_config=""
   if test x"${NTBTLS_CONFIG}" = x -a x"$GPGRT_CONFIG" != x -a "$GPGRT_CONFIG" != "no"; then
     if CC=$CC $GPGRT_CONFIG ntbtls >/dev/null 2>&1; then
       NTBTLS_CONFIG="$GPGRT_CONFIG ntbtls"
       use_gpgrt_config=yes
     fi
   fi
   if test -z "$use_gpgrt_config"; then
     AC_PATH_PROG(NTBTLS_CONFIG, ntbtls-config, no)
   fi
 
   tmp=ifelse([$1], ,1:1.0.0,$1)
   if echo "$tmp" | grep ':' >/dev/null 2>/dev/null ; then
      req_ntbtls_api=`echo "$tmp"     | sed 's/\(.*\):\(.*\)/\1/'`
      min_ntbtls_version=`echo "$tmp" | sed 's/\(.*\):\(.*\)/\2/'`
   else
      req_ntbtls_api=0
      min_ntbtls_version="$tmp"
   fi
 
   AC_MSG_CHECKING(for NTBTLS - version >= $min_ntbtls_version)
   ok=no
   if test "$NTBTLS_CONFIG" != "no" ; then
     req_major=`echo $min_ntbtls_version | \
                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
     req_minor=`echo $min_ntbtls_version | \
                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
     req_micro=`echo $min_ntbtls_version | \
                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
-    ntbtls_config_version=`CC=$CC $NTBTLS_CONFIG --modversion`
+    if test -z "$use_gpgrt_config"; then
+      ntbtls_config_version=`CC=$CC $NTBTLS_CONFIG --version`
+    else
+      ntbtls_config_version=`CC=$CC $NTBTLS_CONFIG --modversion`
+    fi
     major=`echo $ntbtls_config_version | \
                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
     minor=`echo $ntbtls_config_version | \
                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
     micro=`echo $ntbtls_config_version | \
                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
     if test "$major" -gt "$req_major"; then
         ok=yes
     else
         if test "$major" -eq "$req_major"; then
             if test "$minor" -gt "$req_minor"; then
                ok=yes
             else
                if test "$minor" -eq "$req_minor"; then
                    if test "$micro" -ge "$req_micro"; then
                      ok=yes
                    fi
                fi
             fi
         fi
     fi
   fi
   if test $ok = yes; then
     AC_MSG_RESULT([yes ($ntbtls_config_version)])
   else
     AC_MSG_RESULT(no)
   fi
   if test $ok = yes; then
      # If we have a recent ntbtls, we should also check that the
      # API is compatible
      if test "$req_ntbtls_api" -gt 0 ; then
-        tmp=`CC=$CC $NTBTLS_CONFIG --variable=api_version 2>/dev/null || echo 0`
+        if test -z "$use_gpgrt_config"; then
+          tmp=`CC=$CC $NTBTLS_CONFIG --api-version 2>/dev/null || echo 0`
+        else
+          tmp=`CC=$CC $NTBTLS_CONFIG --variable=api_version 2>/dev/null || echo 0`
+	fi
         if test "$tmp" -gt 0 ; then
            AC_MSG_CHECKING([NTBTLS API version])
            if test "$req_ntbtls_api" -eq "$tmp" ; then
              AC_MSG_RESULT([okay])
            else
              ok=no
              AC_MSG_RESULT([does not match. want=$req_ntbtls_api got=$tmp])
            fi
         fi
      fi
   fi
   if test $ok = yes; then
     NTBTLS_CFLAGS=`CC=$CC $NTBTLS_CONFIG --cflags`
     NTBTLS_LIBS=`CC=$CC $NTBTLS_CONFIG --libs`
     ifelse([$2], , :, [$2])
-    ntbtls_config_host=`CC=$CC $NTBTLS_CONFIG --variable=host 2>/dev/null || echo none`
+    if test -z "$use_gpgrt_config"; then
+      ntbtls_config_host=`CC=$CC $NTBTLS_CONFIG --host 2>/dev/null || echo none`
+    else
+      ntbtls_config_host=`CC=$CC $NTBTLS_CONFIG --variable=host 2>/dev/null || echo none`
+    fi
     if test x"$ntbtls_config_host" != xnone ; then
       if test x"$ntbtls_config_host" != x"$host" ; then
   AC_MSG_WARN([[
 ***
 *** The config script "$NTBTLS_CONFIG" was
 *** built for $ntbtls_config_host and thus may not match the
 *** used host $host.
 *** You may want to use the configure option --with-ntbtls-prefix
 *** to specify a matching config script or use \$SYSROOT.
 ***]])
         gpg_config_script_warn="$gpg_config_script_warn ntbtls"
       fi
     fi
   else
     NTBTLS_CFLAGS=""
     NTBTLS_LIBS=""
     ifelse([$3], , :, [$3])
   fi
   AC_SUBST(NTBTLS_CFLAGS)
   AC_SUBST(NTBTLS_LIBS)
 ])